Содержание

Создание смарт контрактов на Ethereum

Создавать смарт-контракты в сети Ethereum достаточно просто. Существует несколько инструментов для разработки смарт-контрактов. Для  программирования первого смарт контракта на Ethereum, пожалуй, удобнее всего подходит среда разработки Remix. Remix удобен тем, что открывается прямо в браузере, и не требует установки на компьютер.

Шаг 1. Среда разработки Remix

Введите в адресной строке браузера “remix.ethereum.org” и нажмите enter. Перед Вами откроется примерно следующая страница:

 

Удалите из Remix весь код. Скопируйте следующий код и вставьте его в Remix:

pragma solidity ^0.4.16;

interface tokenRecipient { function receiveApproval(address _from, uint256 _value, address _token, bytes _extraData) public; }

contract TokenERC20 {
    // Public variables of the token
    string public name;
    string public symbol;
    uint8 public decimals = 18;
    // 18 decimals is the strongly suggested default, avoid changing it
    uint256 public totalSupply;

    // This creates an array with all balances
    mapping (address => uint256) public balanceOf;
    mapping (address => mapping (address => uint256)) public allowance;

    // This generates a public event on the blockchain that will notify clients
    event Transfer(address indexed from, address indexed to, uint256 value);

    // This notifies clients about the amount burnt
    event Burn(address indexed from, uint256 value);

    /**
     * Constrctor function
     *
     * Initializes contract with initial supply tokens to the creator of the contract
     */
    function TokenERC20(
        uint256 initialSupply,
        string tokenName,
        string tokenSymbol
    ) public {
        totalSupply = initialSupply * 10 ** uint256(decimals);  // Update total supply with the decimal amount
        balanceOf[msg.sender] = totalSupply;                // Give the creator all initial tokens
        name = tokenName;                                   // Set the name for display purposes
        symbol = tokenSymbol;                               // Set the symbol for display purposes
    }

    /**
     * Internal transfer, only can be called by this contract
     */
    function _transfer(address _from, address _to, uint _value) internal {
        // Prevent transfer to 0x0 address. Use burn() instead
        require(_to != 0x0);
        // Check if the sender has enough
        require(balanceOf[_from] >= _value);
        // Check for overflows
        require(balanceOf[_to] + _value > balanceOf[_to]);
        // Save this for an assertion in the future
        uint previousBalances = balanceOf[_from] + balanceOf[_to];
        // Subtract from the sender
        balanceOf[_from] -= _value;
        // Add the same to the recipient
        balanceOf[_to] += _value;
        Transfer(_from, _to, _value);
        // Asserts are used to use static analysis to find bugs in your code. They should never fail
        assert(balanceOf[_from] + balanceOf[_to] == previousBalances);
    }

    /**
     * Transfer tokens
     *
     * Send `_value` tokens to `_to` from your account
     *
     * @param _to The address of the recipient
     * @param _value the amount to send
     */
    function transfer(address _to, uint256 _value) public {
        _transfer(msg.sender, _to, _value);
    }

    /**
     * Transfer tokens from other address
     *
     * Send `_value` tokens to `_to` on behalf of `_from`
     *
     * @param _from The address of the sender
     * @param _to The address of the recipient
     * @param _value the amount to send
     */
    function transferFrom(address _from, address _to, uint256 _value) public returns (bool success) {
        require(_value <= allowance[_from][msg.sender]);     // Check allowance
        allowance[_from][msg.sender] -= _value;
        _transfer(_from, _to, _value);
        return true;
    }

    /**
     * Set allowance for other address
     *
     * Allows `_spender` to spend no more than `_value` tokens on your behalf
     *
     * @param _spender The address authorized to spend
     * @param _value the max amount they can spend
     */
    function approve(address _spender, uint256 _value) public
        returns (bool success) {
        allowance[msg.sender][_spender] = _value;
        return true;
    }

    /**
     * Set allowance for other address and notify
     *
     * Allows `_spender` to spend no more than `_value` tokens on your behalf, and then ping the contract about it
     *
     * @param _spender The address authorized to spend
     * @param _value the max amount they can spend
     * @param _extraData some extra information to send to the approved contract
     */
    function approveAndCall(address _spender, uint256 _value, bytes _extraData)
        public
        returns (bool success) {
        tokenRecipient spender = tokenRecipient(_spender);
        if (approve(_spender, _value)) {
            spender.receiveApproval(msg.sender, _value, this, _extraData);
            return true;
        }
    }

    /**
     * Destroy tokens
     *
     * Remove `_value` tokens from the system irreversibly
     *
     * @param _value the amount of money to burn
     */
    function burn(uint256 _value) public returns (bool success) {
        require(balanceOf[msg.sender] >= _value);   // Check if the sender has enough
        balanceOf[msg.sender] -= _value;            // Subtract from the sender
        totalSupply -= _value;                      // Updates totalSupply
        Burn(msg.sender, _value);
        return true;
    }

    /**
     * Destroy tokens from other account
     *
     * Remove `_value` tokens from the system irreversibly on behalf of `_from`.
     *
     * @param _from the address of the sender
     * @param _value the amount of money to burn
     */
    function burnFrom(address _from, uint256 _value) public returns (bool success) {
        require(balanceOf[_from] >= _value);                // Check if the targeted balance is enough
        require(_value <= allowance[_from][msg.sender]);    // Check allowance
        balanceOf[_from] -= _value;                         // Subtract from the targeted balance
        allowance[_from][msg.sender] -= _value;             // Subtract from the sender's allowance
        totalSupply -= _value;                              // Update totalSupply
        Burn(_from, _value);
        return true;
    }
}

Данный код скопирован с сайта ethereum.org/token

Этот код написан на языке программирования Solidity. Solidity применяется чаще всего для разработки смарт контрактов на Ethereum. На нашем сайте есть документация Solidity на русском языке.

Шаг 2. Компиляция кода в Remix

В Remix в правой части Вы увидите как скомпилировался код. Если код не скомпилировался автоматически, то нажмите кнопку “Start to compile”. Поставьте галочку рядом с “Auto compile” для автоматической компиляции в дальнейшем.

После компиляции Вы должны увидеть примерно следующее:

Компиляция кода в Remix

Здесь видно, что компиляция прошла успешно, ошибок в коде нет. И теперь можно загрузить контракт в сеть Ethereum или, как говорят, “задеплоить” (deploy c англ. — развертывание).

Шаг 3. Развертывание контракта в Ethereum через Remix

Для деплоя нужно перейти на вкладку Run и выполнить некоторые настройки. В Environment нужно выбрать “Javascript VM”. Это нужно для того, чтобы контракт деплоился локально. При этом в поле Account Вы увидите несколько аккаунтов со 100 ether на балансе. В сети Ethereum контракты должны деплоиться с конкретного аккаунта, а на счете этого аккаунта должно быть достаточно ether. В Remix для локальной разработки предоставляется несколько таких аккаунтов. Далее, ниже есть поле для выбора контракта для деплоя. В данном случае должен быть выбран контракт TokenERC20. Затем, рядом с кнопкой “Create” нужно заполнить 3 параметра. Это initialSupply — количество выпускаемых токенов, tokenName — название токена, tokenSymbol — символ токена. Заполнять нужно примерно так — 1000, “Token Name”, “TNS”. То есть через запятую, а tokenName и tokenSymbol должны быть в кавычках. У Вас должно получиться примерно следующее:

Деплой контракта в Remix

После этого нужно нажать кнопку “Create”. В результате Вы должны увидеть задеплоенный смарт-контракт:

Смарт контракт в Remix

Нажмите на кнопку totalSupply. Вы должны увидеть:

Remix totalSupply

Это общее количество выпущенных токенов. Несмотря на то, что я указал 1000, totalSupply равен 1000 * 10 ** 18 (в 18 степени). Так получилось благодаря формуле в коде контракта:

totalSupply = initialSupply * 10 ** uint256(decimals);

А вверху кода контракта decimals = 18 (“uint8 public decimals = 18;”). Здесь указано 18, потому что криптовалюта ether имеет дробные единицы, и минимальная единица называется wei. 1 ether = 1 000 000 000 000 000 000 wei (здесь 18 нулей). Поэтому принято указывать decimals равным 18.

При нажатии на кнопки symbol, name, decimals Вы увидите значения, которые хранятся в соответствующих переменных. Ниже идут mappings и функции. Все, что находится в данном интерфейсе, имеет спецификатор видимости public в коде контракта. Например, function transferFrom (…) public.

Подробный разбор данного кода смотрите в уроке “Создание токена ERC20 в Ethereum для ICO“.

Как развернуть контракт в тестовой сети Эфириума смотрите в этом уроке “Деплой (развертывание) смарт-контракта в сеть Ethereum“.

Материал был полезен? Поделитесь в соц. сетях:
Логотип echain.ru

Добавить комментарий

Ваш e-mail не будет опубликован.